mirror of
https://github.com/bitcoin/bitcoin.git
synced 2025-02-10 10:52:31 -05:00
b2135359b3
7a49cacMerge #410: Add string.h include to ecmult_impl0bbd5d4Add string.h include to ecmult_implc5b32e1Merge #405: Make secp256k1_fe_sqrt constant time926836aMake secp256k1_fe_sqrt constant timee2a8e92Merge #404: Replace 3M + 4S doubling formula with 2M + 5S one8ec49d8Add note about 2M + 5S doubling formula5a91bd7Merge #400: A couple minor cleanupsac01378build: add -DSECP256K1_BUILD to benchmark_internal build flagsa6c6f99Remove a bunch of unused stdlib #includes65285a6Merge #403: configure: add flag to disable OpenSSL testsa9b2a5dconfigure: add flag to disable OpenSSL testsb340123Merge #402: Add support for testing quadratic residuese6e9805Add function for testing quadratic residue field/group elements.efd953aAdd Jacobi symbol test via GMPfa36a0dMerge #401: ecmult_const: unify endomorphism and non-endomorphism skew casesc6191fdecmult_const: unify endomorphism and non-endomorphism skew cases0b3e618Merge #378: .gitignore build-aux cleanup6042217Merge #384: JNI: align shared files copyright/comments to bitcoinj's24ad20fMerge #399: build: verify that the native compiler works for static precompb3be852Merge #398: Test whether ECDH and Schnorr are enabled for JNIaa0b1fdbuild: verify that the native compiler works for static precompeee808dTest whether ECDH and Schnorr are enabled for JNI7b0fb18Merge #366: ARM assembly implementation of field_10x26 inner (rebase of #173)001f176ARM assembly implementation of field_10x26 inner0172be9Merge #397: Small fixes for sha2563f8b78eFix undefs in hash_impl.h2ab4695Fix state size in sha256 struct6875b01Merge #386: Add some missing `VERIFY_CHECK(ctx != NULL)`2c52b5dMerge #389: Cast pointers through uintptr_t under JNI43097a4Merge #390: Update bitcoin-core GitHub links31c9c12Merge #391: JNI: Only call ecdsa_verify if its inputs parsed correctly1cb2302Merge #392: Add testcase which hits additional branch in secp256k1_scalar_sqrd2ee340Merge #388: bench_ecdh: fix call to secp256k1_context_create093a497Add testcase which hits additional branch in secp256k1_scalar_sqra40c701JNI: Only call ecdsa_verify if its inputs parsed correctlyfaa2a11Update bitcoin-core GitHub links47b9e78Cast pointers through uintptr_t under JNIf36f9c6bench_ecdh: fix call to secp256k1_context_createbcc4881Add some missing `VERIFY_CHECK(ctx != NULL)` for functions that use `ARG_CHECK`6ceea2calign shared files copyright/comments to bitcoinj's70141a8Update .gitignore7b549b1Merge #373: build: fix x86_64 asm detection for some compilersbc7c93cMerge #374: Add note about y=0 being possible on one of the sextic twistse457018Merge #364: JNI rebased86e2d07JNI library: cleanup, removed unimplemented code3093576aJNI librarybd2895fMerge pull request #371e72e93aAdd note about y=0 being possible on one of the sextic twists3f8fdfbbuild: fix x86_64 asm detection for some compilerse5a9047[Trivial] Remove double semicolonsc18b869Merge pull request #3603026daaMerge pull request #30203d4611Add sage verification script for the group lawsa965937Merge pull request #36183221ecAdd experimental features to configure5d4c5a3Prevent damage_array in the signature test from going out of bounds.419bf7fMerge pull request #35603d84a4Benchmark against OpenSSL verification git-subtree-dir: src/secp256k1 git-subtree-split:7a49cacd39
65 lines
2.1 KiB
Text
65 lines
2.1 KiB
Text
dnl libsecp25k1 helper checks
|
|
AC_DEFUN([SECP_INT128_CHECK],[
|
|
has_int128=$ac_cv_type___int128
|
|
])
|
|
|
|
dnl escape "$0x" below using the m4 quadrigaph @S|@, and escape it again with a \ for the shell.
|
|
AC_DEFUN([SECP_64BIT_ASM_CHECK],[
|
|
AC_MSG_CHECKING(for x86_64 assembly availability)
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <stdint.h>]],[[
|
|
uint64_t a = 11, tmp;
|
|
__asm__ __volatile__("movq \@S|@0x100000000,%1; mulq %%rsi" : "+a"(a) : "S"(tmp) : "cc", "%rdx");
|
|
]])],[has_64bit_asm=yes],[has_64bit_asm=no])
|
|
AC_MSG_RESULT([$has_64bit_asm])
|
|
])
|
|
|
|
dnl
|
|
AC_DEFUN([SECP_OPENSSL_CHECK],[
|
|
has_libcrypto=no
|
|
m4_ifdef([PKG_CHECK_MODULES],[
|
|
PKG_CHECK_MODULES([CRYPTO], [libcrypto], [has_libcrypto=yes],[has_libcrypto=no])
|
|
if test x"$has_libcrypto" = x"yes"; then
|
|
TEMP_LIBS="$LIBS"
|
|
LIBS="$LIBS $CRYPTO_LIBS"
|
|
AC_CHECK_LIB(crypto, main,[AC_DEFINE(HAVE_LIBCRYPTO,1,[Define this symbol if libcrypto is installed])],[has_libcrypto=no])
|
|
LIBS="$TEMP_LIBS"
|
|
fi
|
|
])
|
|
if test x$has_libcrypto = xno; then
|
|
AC_CHECK_HEADER(openssl/crypto.h,[
|
|
AC_CHECK_LIB(crypto, main,[
|
|
has_libcrypto=yes
|
|
CRYPTO_LIBS=-lcrypto
|
|
AC_DEFINE(HAVE_LIBCRYPTO,1,[Define this symbol if libcrypto is installed])
|
|
])
|
|
])
|
|
LIBS=
|
|
fi
|
|
if test x"$has_libcrypto" = x"yes" && test x"$has_openssl_ec" = x; then
|
|
AC_MSG_CHECKING(for EC functions in libcrypto)
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <openssl/ec.h>
|
|
#include <openssl/ecdsa.h>
|
|
#include <openssl/obj_mac.h>]],[[
|
|
EC_KEY *eckey = EC_KEY_new_by_curve_name(NID_secp256k1);
|
|
ECDSA_sign(0, NULL, 0, NULL, NULL, eckey);
|
|
ECDSA_verify(0, NULL, 0, NULL, 0, eckey);
|
|
EC_KEY_free(eckey);
|
|
]])],[has_openssl_ec=yes],[has_openssl_ec=no])
|
|
AC_MSG_RESULT([$has_openssl_ec])
|
|
fi
|
|
])
|
|
|
|
dnl
|
|
AC_DEFUN([SECP_GMP_CHECK],[
|
|
if test x"$has_gmp" != x"yes"; then
|
|
CPPFLAGS_TEMP="$CPPFLAGS"
|
|
CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
|
|
LIBS_TEMP="$LIBS"
|
|
LIBS="$GMP_LIBS $LIBS"
|
|
AC_CHECK_HEADER(gmp.h,[AC_CHECK_LIB(gmp, __gmpz_init,[has_gmp=yes; GMP_LIBS="$GMP_LIBS -lgmp"; AC_DEFINE(HAVE_LIBGMP,1,[Define this symbol if libgmp is installed])])])
|
|
CPPFLAGS="$CPPFLAGS_TEMP"
|
|
LIBS="$LIBS_TEMP"
|
|
fi
|
|
])
|